@echo off
title Valu-Basic

:: Pfade ermitteln
set STICK=%~dp0
set PHP=%STICK%php\php.exe
set APP=%STICK%valu-basic
set PORT=8080
set DB=%APP%\data\valu_basic.sqlite

:: PHP prüfen
if not exist "%PHP%" (
    echo.
    echo FEHLER: PHP nicht gefunden!
    echo Bitte den USB-Stick vollstaendig kopieren.
    echo.
    pause
    exit /b 1
)

:: Port prüfen ob bereits belegt
netstat -an 2>nul | find ":%PORT% " >nul
if %errorlevel% == 0 (
    echo Port %PORT% ist bereits belegt.
    echo Valu-Basic laeuft moeglicherweise bereits.
    start "" "http://localhost:%PORT%"
    timeout /t 3 >nul
    exit /b 0
)

:: Starten
cls
echo.
echo  Valu-Basic startet...
echo  Bitte warten - Browser oeffnet sich gleich.
echo.

start /b "" "%PHP%" -c "%STICK%php\php.ini" -S localhost:%PORT% -t "%APP%"
timeout /t 2 >nul

:: Erste Nutzung: init_sqlite, danach: login
if not exist "%DB%" (
    echo  Erste Nutzung - Setup wird gestartet...
    start "" "http://localhost:%PORT%/init_sqlite.php"
) else (
    start "" "http://localhost:%PORT%/login.php"
)

echo  Valu-Basic laeuft auf http://localhost:%PORT%
echo.
echo  WICHTIG: Dieses Fenster NICHT schliessen!
echo  Zum Beenden: Fenster schliessen oder Strg+C druecken.
echo.

:wait
timeout /t 60 >nul
netstat -an 2>nul | find ":%PORT% " >nul
if %errorlevel% == 0 goto wait

echo  Valu-Basic wurde beendet.
timeout /t 3 >nul
